Twin Keepers Campaign: Tub Vulnerabilities Problem

[rhatswell]

Hi new member here. First time posting.

I wonder if I could get some help please if possible. I'm at a complete loss here.

I'm currently working my way through the additional campaigns using the latest version of KeeperFX (v0.4.6). I'm currently playing the "Twin Keepers" campaign. I seem to be completely stuck on Level 5 - "Tub vulnerabilities 1.1.0". I can play the level and I can beat all 3 rival dungeons and the raiding hero parties but then I'm left with nothing to do. I assumed that once all the heroes and rival keepers were destroyed I would win the level. It seems like I can't progress. I've been exploring the map trying to trigger a hero ambush but to no avail. I have played the level 3 times but each time I get to the same point. Am I missing something really obvious here or is it a bug on the map? I have taken a look at the script for the level but as I don't have much experience with code, I'm not exactly sure what is required to win the level. Any help would be greatly appreciated.

[YourMaster]

Welcome.

Well, actually that is the win-condition. After the six hero parties spawn - the final one has the lvl10 knight, all you have to do is kill all the good creatures to win the level. They do seem to run from you though as soon as the knight is defeated, so look around the map and find the hidden hero.
It's not just the heroes that spawn, if there are some preplaced heroes in hidden corners, they also need to die.

[rhatswell]

Thanks for your reply.

So the win condition is to kill all the good creatures! I thought that was the case. Does it matter if a rival dungeon help kill the heroes? I took over the yellow dungeon and used the "Reveal Map" special box so I know there are definitely no additional heroes hanging around...

[YourMaster]

Make a saved game and share it here, so I can take a look.

It does not matter who killed the heroes.
The victory conditions are:

PLAYER0,FLAG0 == 2
and
PLAYER_GOOD,TOTAL_CREATURES == 0

So all that matters is that there are no good creatures left. That flag goes to 2 about a minute after the hero parties begin to spawn, so it makes sure that you don't win before the heroes start to spawn.

[Woudo]

Can't have any prisoners or torture chamber members either. No white dots anywhere on the map.

[rhatswell]

OK since playing the level again, I managed to progress and complete the level. It looks like Player0 has to be the one that needs to kill the Knight. This time, the yellow dungeon did not break out so I was unable to get to them so I let them be. The hero parties destroyed the blue/purple and green dungeons and I finished the heroes off. As soon as my Mistresses killed the Knight, I had a pop up saying to kill the last remaining heroes and as soon as I did that, I conquered the realm. Before, I was allowing the rival dungeons to kill the heroes including the Knight. I think that's where you get stuck if that happens. Thanks for all your help though.

[YourMaster]

Sorry, that simply isn't possible. I'm happy to accept both you missing something or the game bugging out somehow, but there's nothing programmed that allows the game to determine which player killed which creature. So like I said, it does not matter if you or any other keeper killed the knight.
In any case, you've passed the level, so fine.

[Woudo]

Now hang on a minute here, princess. I'm the boss of this gym. I'll look at the script and tell him what can and cannot happen.

[Woudo]

IF(PLAYER0,GAME_TURN > 49500)
    SET_TIMER(PLAYER0,TIMER0)
    SET_FLAG(PLAYER0,FLAG0,1)
ENDIF

IF_ACTION_POINT(5,PLAYER0)
    SET_TIMER(PLAYER0,TIMER0)
    SET_FLAG(PLAYER0,FLAG0,1)
ENDIF

-----------

IF(PLAYER0,FLAG0 == 1)
    IF(PLAYER0,TIMER0 > 500)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTY6,-1,1)
        DISPLAY_OBJECTIVE(30,PLAYER0)
    ENDIF
    IF(PLAYER0,TIMER0 > 600)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTY5,-1,2)
    ENDIF
    IF(PLAYER0,TIMER0 > 700)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTY4,4,1)
    ENDIF
    IF(PLAYER0,TIMER0 > 800)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTY3,-1,2)
    ENDIF
    IF(PLAYER0,TIMER0 > 900)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTY2,-1,2)
    ENDIF
    IF(PLAYER0,TIMER0 > 1000)
        ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTY1,-1,1)
    ENDIF
    IF(PLAYER0,TIMER0 > 1100)
        SET_FLAG(PLAYER0,FLAG0,2)
    ENDIF
ENDIF

--------------------

IF(PLAYER0,FLAG0 == 2)
    IF(PLAYER_GOOD,KNIGHT == 0)
        DISPLAY_OBJECTIVE(29,PLAYER0)
        SET_CREATURE_FEAR(ARCHER,255)
        SET_CREATURE_FEAR(BARBARIAN,255)
        SET_CREATURE_FEAR(DWARFA,255)
        SET_CREATURE_FEAR(FAIRY,255)
        SET_CREATURE_FEAR(GIANT,255)
        SET_CREATURE_FEAR(MONK,255)
        SET_CREATURE_FEAR(SAMURAI,255)
        SET_CREATURE_FEAR(THIEF,255)
        SET_CREATURE_FEAR(WITCH,255)
        SET_CREATURE_FEAR(WIZARD,255)
    ENDIF
    IF(PLAYER_GOOD,TOTAL_CREATURES == 0)
        DISPLAY_OBJECTIVE(28,PLAYER0)
        WIN_GAME
    ENDIF
ENDIF

Action Point 5 is in a tiny pathway separating yellow and the "upstream" part, where the heroes spawn. The player can only access it by stealing Destroy_Walls from Green.

Basically, if you step into that tiny pathway for the first time after the final party has spawned but before they're all dead (such as if they're chillin' in prison or still walking to your base) then you will trigger the action point and reset P0 FLAG0-2 back to P0 FLAG0-1. With P0 FLAG0 not set to 2, the victory condition won't fire.

[YourMaster]

You're right, that's a bug in the level,... there are two ways to trigger FLAG0. That doesn't conflict what I said that it does not matter who kills a knight as long as it's killed.
This script should fix it:

IF(PLAYER0,FLAG0 == 0)
	IF(PLAYER0,GAME_TURN > 49500)
		SET_TIMER(PLAYER0,TIMER0)
		SET_FLAG(PLAYER0,FLAG0,1)
	ENDIF
ENDIF

IF_ACTION_POINT(1,PLAYER0)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTY8,2,1)
    ADD_PARTY_TO_LEVEL(PLAYER_GOOD,PARTY7,3,1)
ENDIF

IF(PLAYER0,FLAG0 == 0)
	IF_ACTION_POINT(5,PLAYER0)
		SET_TIMER(PLAYER0,TIMER0)
		SET_FLAG(PLAYER0,FLAG0,1)
	ENDIF
ENDIF

I don't feel like playtesting this level. Woudo, do you see anything wrong with this, or do you agree that this would fix it?

EDIT: For future reference, if you visit this topic because you have this topic, extract this file to your keeperfx\campgns\twinkprs directory: map00207.zip